| トップページ＞3Dグラフィックス POV-Ray＞東京ドームシティの観覧車<BIG-O> | 
|
 |
|
東京ドームシティの観覧車<BIG-O> |
POV-Rayを数年程全くいじっていなかった状態で谷津遊園の観覧車を
作ることになったので準備運動でかなりおおざっぱに作ったものです。
写真が沢山あるのでそのうち細かいところも作ります。
ジェットコースターがくぐり抜けます。
//ooooooooooooooooooooooooooooooooo
//東京ドームシティアトラクションズ
//観覧車"BIG-O"ver.20070919
//POV-Ray for Windows v3.6
//+W1200 +H900 +FN +A0.3
//ooooooooooooooooooooooooooooooooo
#include "colors.inc"
#include "skies.inc"
camera{
//上から見おろす
location<3,1,2.5>
look_at<0,-0.3,0>
//下から見上げる
//location<2,-1.6,2>
//look_at<0,0,0>
angle 55
}
light_source{<10,20,-10> White*2}
/*
sphere{<0,0,0>0.1 pigment{Yellow}}//中心
cylinder{<8,0,0><-8,0,0>0.01 pigment{color Blue}}//X
cylinder{<0,8,0><0,-8,0>0.01 pigment{color Green}}//Y
cylinder{<0,0,8><0,0,-8>0.01 pigment{color Red}}//Z
*/
//本体
torus{1 ,.01 pigment{White*2} rotate z*90 translate x* .05}
torus{1 ,.01 pigment{White*2} rotate z*90 translate x*-.05}
torus{.8,.01 pigment{White*2} rotate z*90}
#declare A=union{
//白い斜めの棒
cylinder{<0,0,.8>< .05,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)>.005 pigment{White*2}}
cylinder{<0,0,.8>< .05,1.0*sin( 2*pi/40),1.0*cos( 2*pi/40)>.005 pigment{White*2}}
cylinder{<0,0,.8><-.05,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)>.005 pigment{White*2}}
cylinder{<0,0,.8><-.05,1.0*sin( 2*pi/40),1.0*cos( 2*pi/40)>.005 pigment{White*2}}
//横棒
cylinder{<.05,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)><-.05,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)>.005 pigment{White*2}}
cylinder{<.05,1.0*sin( 2*pi/40),1.0*cos( 2*pi/40)><-.05,1.0*sin( 2*pi/40),1.0*cos( 2*pi/40)>.005 pigment{White*2}}
}
#declare i=0;
#while (i<20)
object{A rotate x*i*360/20}
#declare i=i+1;
#end
//ゴンドラをぶら下げる棒
#declare B=union{
//青い斜めの棒
cylinder{< .05,0,1.1>< .05,1.0*sin(-2*pi/80),1.0*cos(-2*pi/80)>.005 pigment{MediumBlue*2}}
cylinder{< .05,0,1.1>< .05,1.0*sin( 2*pi/80),1.0*cos( 2*pi/80)>.005 pigment{MediumBlue*2}}
cylinder{<-.05,0,1.1><-.05,1.0*sin(-2*pi/80),1.0*cos(-2*pi/80)>.005 pigment{MediumBlue*2}}
cylinder{<-.05,0,1.1><-.05,1.0*sin( 2*pi/80),1.0*cos( 2*pi/80)>.005 pigment{MediumBlue*2}}
//横棒
cylinder{< .05,0,1.1><-.05,0,1.1>.005 pigment{MediumBlue*2}}
}
#declare j=0;
#while (j<40)
object{B rotate x*j*360/40}
#declare j=j+1;
#end
//ゴンドラ
#declare k=0;
#while (k<40)
cylinder{< .03,1.1*sin(k*2*pi/40)-.05,1.1*cos(k*2*pi/40)>
<-.03,1.1*sin(k*2*pi/40)-.05,1.1*cos(k*2*pi/40)>
.04 pigment{Red*2}}
#declare k=k+1;
#end
//外側支柱
#declare outerpost=union{
cylinder{< .06,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)>
< .3,-1.2,.8>
.02 pigment{Blue*2}}
cylinder{< .06,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)>
< .3,-1.2,.5>
0.02 pigment{Blue*2}}
cylinder{<-.06,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)>
<-.3,-1.2,.8>
0.02 pigment{Blue*2}}
cylinder{<-.06,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)>
<-.3,-1.2,.5>
.02 pigment{Blue*2}}
}
object{outerpost}
object{outerpost rotate y*180}
//内側支柱
#declare innerpost=union{
cylinder{< .06,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)>< .15,-1.2,.8>.02 pigment{Blue*2}}
cylinder{< .06,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)>< .15,-1.2,.5>.02 pigment{Blue*2}}
cylinder{<-.06,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)><-.15,-1.2,.8>.02 pigment{Blue*2}}
cylinder{<-.06,1.0*sin(-2*pi/40),1.0*cos(-2*pi/40)><-.15,-1.2,.5>.02 pigment{Blue*2}}
}
object{innerpost}
object{innerpost rotate y*180}
//台
box{<.4,-1.4,1.0><-.4,-1.2,-1.0>pigment{Gray35}}
//背景
sky_sphere{
pigment{
gradient -x
color_map{[.1 White*.8][1 SkyBlue]}
}
}
|